Henry,

Thank you for your postings for sharing the PP+ formulae. It accelerates my learning curve. I have bought the PP+ for a few days. I have the following questions:

1. I tried to download the Henry's PP+ Toolkit. A message of "No importable file exist in the source folder." Is the file damage?

2. Some of the external formula which in your postings do not include explaination of their function in the PP+ manual. For example: ExtFml("PowerPivots.SysEval",LE,LX,SE,SX,"!@#$#@!") ,ExtFml("PowerPivots.PivotTrigger") and ExtFml("PowerPivots.TDataCreate",1, factor), ExtFml("PowerPivots.TDataLocalize", UCloud, factor, offset). Where can I get a complete list of all the external formula include in the pp+ software?

3.The manual suggested to visit www.marketangel.com for additional information is not work. Do you know where is the new website?


Thank you in advance!

If you downloaded the PP+ Toolkit , instead of trying to import it through Metastock, simply double click on the file and it should self install.

to create a system you need to define the 4 variables LE {Long Entry} SE {Short entry} LX { Long exit} SX { Short exit}

then B:=ExtFml("PowerPivots.SysEval",LE,LX,SE,SX,"!@#$#@!") ;{Do not change any of the typeset}

ExtFml("PowerPivots.TDataCreate",0, factor), is the open price factor is the time frame 1 would be the current time frame , 2 would be a weekly time frame on a daily chart

ExtFml("PowerPivots.TDataCreate",1, factor) is the high price

ExtFml("PowerPivots.TDataCreate",2, factor) is the low price

ExtFml("PowerPivots.TDataCreate",3, factor) is the close price

once you have created a multi time frame Variable you need to use

ExtFml("PowerPivots.TDataLocalize", {Variable}, factor, offset)

to plot it, offset is just how many bars to reset it to the right

A plug-in is developed by and supported by Equis. (http://forum.equis.com/viewtopic.php?t=2582)

According to Equis website:http://www.equis.com/products/thirdparty/?PLUG-PPP, PP+ is a plugin. Therefore, I think Equis has a full (fool) supported in the product. Eventhough I know other website sells PP+ cheaper than Equis, I still bought from Equis.

I asked Equis for the same questions of my last posting, they just told me that Market Angel web site has been inactive for quite some time. They told me to find other users of PP+ in Yahoo group or this Forum to help. I have been kept waiting for approval of membership of Yahoo PP+ group for a week and the group is inactive for 3 months. Therefore, the only support I can get is this Forum.

Henry,

Do you know you are now the only support of PP+ in this world?

In fact from your previous postings of PP+ formula, if the manual has explained the functions, I can learn a lot how to use these external formula. (For example, the manual explains that ExtFml( "PowerPivots.TrendDirection",PivotStrength, TFACTOR) determines the direction of the trend. If it return +1 it is uptrend. If it returns -1, it is downtrend.) However, since the manual do not explain some external formula. It is very very difficult for me to guess what the return of these function without the explaination. Could you please do me a favour, tell me what is the return of the following functions:

ExtFml( "PowerPivots.ArrayLoad", BIN#, HOOK)

ExtFml( "PowerPivots.ArrayRelease", BIN#, HOOK)

ExtFml( "PowerPivots.ArraySave", BIN#, ARRAY, HOOK)

ExtFml( "PowerPivots.FibLadder", LadderLevel, Length)

ExtFml( "PowerPivots.PivotBreakout", STRENGTH_LongTerm, STRENGTH_ShortTerm)

ExtFml( "PowerPivots.PivotTrigger")

ExtFml( "PowerPivots.RetInd", PlotIx, PivotArray, TrendArray, PivotSTRENGTH, Retrace%)

ExtFml( "PowerPivots.SysEval", LongEntry, LongExit, ShortEntry, ShortExit, HOOK)
Although you have explain in your last posts, I still don't know what is the function returns.

ExtFml( "PowerPivots.TDataCreate", OHLC, TFactor)

ExtFml( "PowerPivots.TDataLocalize", TDataArray, TFactor, Offset)

Thank you in advance!

i:=Input("Lookback Period", 10, 1000, 300);

ExtFml("PowerPivots.FibLadder",-2,i);
ExtFml("PowerPivots.FibLadder",-1,i);
ExtFml("PowerPivots.FibLadder",0,i);
ExtFml("PowerPivots.FibLadder",1,i);
ExtFml("PowerPivots.FibLadder",2,i);
ExtFml("PowerPivots.FibLadder",3,i);
ExtFml("PowerPivots.FibLadder",4,i);
ExtFml("PowerPivots.FibLadder",5,i);
ExtFml("PowerPivots.FibLadder",6,i);
ExtFml("PowerPivots.FibLadder",7,i);
ExtFml("PowerPivots.FibLadder",8,i);
ExtFml("PowerPivots.FibLadder",9,i);
ExtFml("PowerPivots.FibLadder",10,i);



it's a little like Murrey Math

A2:= ExtFml("PowerPivots.TrendDirection",1,2);
If(Sum(A2>0,2)>1,1,If(Sum(A2<0,2)>1,-1,0));

this indicator plots the change of trend from minor pivots from a higher time frame


I use the Sum(function) to avoid any wiggles in the exploration and system test.
This indicator is valid from the first bar signal.
There are no hidden or disappearing signals

length:=Input("Length", 1, 1000, 6);
Factor:=Input("TFactor",0,1000,1);
offset:=Input("Offset", 0, 1000, 0);
Mat:=Input("MA 1=Sim 2=Exp 3=Var 4=Weight 5 =tria 6=Time",1,6,1);
Pct:= Input("Percentage Bands?",0.1,10,5);
SO:=ExtFml("PowerPivots.TDataCreate",0,Factor);{Synthetic Open}
SH:=ExtFml("PowerPivots.TDataCreate",1,Factor);{Synthetic High}
SL:=ExtFml("PowerPivots.TDataCreate",2,Factor);(Synthetic Low}
SC:=ExtFml("PowerPivots.TDataCreate",3,Factor);{Synthetic Close}
Data:=(SO+SH+SL+SC)/4;
X:=If(Mat=1, Mov(Data, length, S),If(Mat=2, Mov(Data, length, E),If(Mat=3, Mov(Data, length, VAR),If(Mat=4, Mov(Data, length, W),If(Mat=5, Mov(Data, length, TRI), Mov(Data, length, T))))));
TBnd:= X*(1+Pct/100);
LBnd:= X*(1-Pct/100);
{To Plot the three values, you need to use TDatalocalize}

MA:=ExtFml("PowerPivots.TDataLocalize", X, factor, offset);
TBnd:=ExtFml("PowerPivots.TDataLocalize", TBnd, factor, offset);
LBnd:=ExtFml("PowerPivots.TDataLocalize", LBnd, factor, offset);
MA;TBnd;LBnd;



Factor is which time frame you want !
Factor=1 is the current time frame of the chart
Factor=2 is the higher time frame, in EOD 2 would be from a weekly chart, IN RT Factor =2 say you were charting a 30 min chart Factor=2 wolud use the time frame of a 60 min chart

Offset would move the plot 1 Time frame bar to the right

ExtFml( "PowerPivots.PivotTrigger")

just plots a binary signal +1 -1 when a pivot level is taken out

This is an expert PP+ Donchain Channel
{Long Entry}

UC:=Ref(HHV(H,10),-1);
LC:=Ref(LLV(L,10),-1);
TD:=ExtFml("PowerPivots.TrendDirection",1,2);
LE:=Cross(C,UC) AND Sum(TD>0,2)>1;
SE:=Cross(LC,C) AND Sum(TD<0,2)>1;
LX:=Cross(LC,C);
SX:=Cross(C,UC);

B:=ExtFml("PowerPivots.SysEval",LE,LX,SE,SX,"!@#$#@!");{Gives a binary signal}

B>0 AND Ref(B,-1)<=0


the use of ExtFml("PowerPivots.SysEval",LE,LX,SE,SX,"!@#$#@!") creates a binary signal or latch. It take the first signal and then waits for the exit or other entry position to return another signal

the old way of creating a latch required the use of Cum(1) and Prev functions which would slow down an exploration

TF:=Input("TFactor",1, 1000, 3);
OF:=Input("Offset", -100, 100, 0);
Plot:=Input("Plot 1=odd 2= even 3= both",1,3,3);
TCH:=ExtFml("PowerPivots.TimeCapsules",H,TF,OF);
TCL:=ExtFml("PowerPivots.TimeCapsules",L,TF,OF);
RNG:=TCH-TCL;
78R:=If(plot<>2,Rng*.875+TCL,TCH);
68R:=If(plot<>1,Rng*.75+TCL,TCH);
58R:=If(plot<>2,Rng*.625+TCL,TCH);
48R:=If(plot<>1,Rng*.5+TCL,TCH);
38R:=If(plot<>2,Rng*.375+TCL,TCH);
28R:=If(plot<>1,Rng*.25+TCL,TCH);
18R:=If(plot<>2,Rng*.125+TCL,TCH);
TCH;78R;68R;58R;48R;38R;28R;18R;TCL;

priceType:=Input("Price (Open=0 High=1 Low=2 Close=3)", 0, 3, 3);
length:=Input("Length", 1, 1000, 20);
factor:=Input("TFactor", 0, 1000, 1);
offset:=Input("Offset", 0, 1000, 0);
Mat:=Input("MA 1=Sim 2=Exp 3=Var 4=Weight 5 =tria 6=Time",1,6,1);
htfData:=ExtFml("PowerPivots.TDataCreate",priceType, factor);
X:=If(Mat=1, Mov(htfData, length, S),If(Mat=2, Mov(htfData, length, E),If(Mat=3, Mov(htfData, length, VAR),If(Mat=4, Mov(htfData, length, W),If(Mat=5, Mov(htfData, length, TRI), Mov(htfData, length, T))))));
results:=ExtFml("PowerPivots.TDataLocalize", x, factor, offset);
results;

a:=ExtFml("PowerPivots.Pivots");
Pivot:=Input("1=minor 2=intermediate 3=Major 4=Primary",1,4,2);
PA:=If(BarsSince(A>=Pivot)<BarsSince(A<=-Pivot),ValueWhen(2,a>=Pivot,H), ValueWhen(2,a<=-Pivot,L));
PB:=If(BarsSince(A>=Pivot)<BarsSince(A<=-pivot),ValueWhen(1,a<=-
pivot,L), ValueWhen(1,a>=pivot,H));
PC:=If(BarsSince(A>=pivot)<BarsSince(A<=-pivot),ValueWhen(1,a>=pivot,H), ValueWhen(1,a<=-pivot,L));
HP:= Max(pa,Max(pb,pc));
LP:= Min(pa,Min(pb,pc));
RET1:=hp-((hp-lp)*0.618);
RET2:=hp-((hp-lp)*0.382);

HP; {Red}
LP; {Green}
RET1; {Blue}
RET2; {BLue}

Re: [PowerPivots] Power Pivots tools


There has been much discussion about signals showing up late in the PowerPivots plugin, and as the developer of the product, I thought it might be helpful if I took a moment to explain exactly what is happening.

First and foremost, it should be understood that the systems that are included with PowerPivots Plus are not actual trading systems -- they are trading models. They were provided with the plugin as an example of how to incorporate pivot and multiple time frame analysis into your existing trading methodology. The real power behind the plugin is in the tools that are provided. Never before have MetaStock users had the ability to easily reference pivot points (to help determine where their stops should go) or reference market data on a higher time frame. To a trader, these tools are invaluable, and some of them are very innovative. The user who is seeking black box systems to just simply spit out buy and sell signals while they sit back and wait for the cash to roll in, is probably going to be very disappointed with my product.

Now, regarding the delayed marking of the bars. A handful of the systems utilize multiple time frame analysis for either their entries or their exits. Lets take the case of a daily chart referencing weekly data. On the daily chart, there are 5 bars that compose any given weekly bar. Lets say that we wanted to go long if the previous high pivot on a weekly chart is violated. Now imagine that for the first 2 days of the week, the market trades below the weekly pivot high, however, on the third day (or bar) the market takes it out. This is where the problem exists. In order for me to mark a bar on 1 time frame, I need to be able to find a corresponding bar on the other time frame. The first bar of the week shares the same date/time as the bar on the weekly chart, therefore, all markings have to be done on that bar.

This is a very important issue regarding multiple time frame analysis. Users need to be aware of the fact that when referencing a higher time frame, marking any given bar on the current time frame is really the same as marking the entire group.

In actuality, this really only becomes an issue to academics. A short signal that shows up on a bar from 3 bars ago doesn't mean that its any less valid than if it showed up on the current bar. To a real-time trader, it still means that they should re-evaluate their market position and seriously consider being short.

I understand that this plugin is quite a bit different than a lot of the previous products that MetaStock users have become accustomed to. Users who are not interested in learning the "craft" of trading will probably be better served purchasing one of the other existing MetaStock plugins.

Starting this week, I will be updating the MarketScope several times a week as I see trades develop. This is really the best way to see how to bring all the components together and use them in real-time trading. You can see it at www.marketangel.com/MarketScope

-Sandon Racowsky



I copied this from the PowerPivot group

i1:=Input("Pivot (1=Minor 2=Interm 3=Major 4=Primary)",1,4,2);
i2:=Input("Trend Direction",1,4,1);
aPivots:= ExtFml("PowerPivots.Pivots");
aTrend:= ExtFml("PowerPivots.TrendDirection",i1,i2);
ExtFml("PowerPivots.RetInd",0,aPivots,aTrend,i1,0);
ExtFml("PowerPivots.RetInd",0,aPivots,aTrend,i1,.125);
ExtFml("PowerPivots.RetInd",0,aPivots,aTrend,i1,.25);
ExtFml("PowerPivots.RetInd",0,aPivots,aTrend,i1,.375);
ExtFml("PowerPivots.RetInd",0,aPivots,aTrend,i1,.5);
ExtFml("PowerPivots.RetInd",0,aPivots,aTrend,i1,.625);
ExtFml("PowerPivots.RetInd",0,aPivots,aTrend,i1,.75);
ExtFml("PowerPivots.RetInd",0,aPivots,aTrend,i1,.875);
ExtFml("PowerPivots.RetInd",1,aPivots,aTrend,i1,.875);
ExtFml("PowerPivots.RetInd",2,aPivots,aTrend,i1,.875);
ExtFml("PowerPivots.RetInd",0,aPivots,aTrend,i1,1);

Henry,

Thank you to take time to explain each ExtFml by examples. Some of them are even password protected indicator of the PP+ plugin. Thank you for your sharing!

While I still digest what you have post, I dicover that sometimes error message appear on ploting the indicator. For example, when I plot your example of Time Average MA (same as the password protected pp+:: T-Average), I can plot on daily chart with TFactor =2 or 3. However, when I change the daily chart to weekly chart, the custom indicator error message: "Period value out of valid range in Mov() function" appears. The same error message appears even I change back to daily timeframe. Nothing can stop the error message except to close MetaStock and plot the indicator again. What 's wrong with that?

For time capsules and OHLC/4 wTDC indicators, only weekly time frame can be plot but not daily timeframe. Why?

Thank you in advance!

the error mesages come from when you change the periodocity of the chart, and the way Metastock calculates the data array and the way the dll reads the new data array. In other words not enough data points to create a value. You might have to load more data on the chart.