{Note: original concepts by Jose Silva. Avail: www.metastocktools.com}
{User Inputs }
pds:=Input("ATR periods",1,252,10);
{ Weekly SMA }
EOW:=Cum(1)=LastValue(Cum(1));
{ Reference EOW signals }
WkEnd:=EOW OR FmlVar("Week's true Start & End","WEEKEND");
{ Week's Close }
WkCl:=ValueWhen(1,WkEnd,C);
WkCl:=ValueWhen(1,WkCl>0,WkCl);
{ Weekly SMA }
z:=Cum(WkEnd*WkCl);
WkSma:=(z-ValueWhen(2,WkEnd,z));
{ ATR Trailing Stop }
StLong:=HHV(WkSma-2.5*Mov(ATR(1),pds,E),21);
StShort:=LLV(WkSma+2.5*Mov(ATR(1),pds,E),21);
stopLong:=If(WkSma<PREV,StLong,Max(StLong,PREV));
stopShort:=If(WkSma>PREV,StShort,Min(StShort,PREV));
{ Trade flags/signals }
In:=Cross(WkSma,Ref(stopShort,-1));
Out:=Cross(Ref(stopLong,-1),WkSma);
Init:=Cum(IsDefined(In+Out))=1;
x:=ValueWhen(1,In-Out<>0 OR Init,In-Out);
long:=x=1 AND (Alert(x<>1,2) OR Init);
short:=x=-1 AND (Alert(x<>-1,2) OR Init);
signals:=long-short;
flag:=ValueWhen(1,signals<>0 OR Init,signals);
{ Switch between Long/Short stops }
stop:=Ref(If(flag=1,stopLong,stopShort),-1);
{ Plot }
stop; If(C>=stop,1,-1)